Author Archives: mmichielin

Ethernet (LAN RJ45) cable tester with Arduino

Posted on by
9

In this article you can find instruction on how to make a simple ethernet cable tester driven by an Arduino.

I was inspired by this page that simply and clearly describes how to make a tester for ethernet cables (straight or cross) with a master and a slave unit, so to be able to test also cable already in place.

I did nothing more than following the instructions and writing few lines of code for Arduino.

Hardware

What you need:

  • eight LED
  • eight resistor (I’ve used 33 ohm resistors)
  • two ethernet plug (female)
  • a switch (to be able to test straight and cross cables)
  • and, obviously, wires and two small pieces of board

We need to build to separate small boards:

  • a master board, that will be inserted into the Arduino and that will be plugged into one side of the ethernet cable that we need to test
  • a slave board, that will be plugged into the other side of the ethernet cable that we need to test

This is the circuit:

Software

The process implemented with the software is very simple:

  • Arduino set an HIGH value (5 V) on each wire of the cable for one second (and then reset a LOW value) one wire after the other
  • If everything is ok, you should see LEDs on the slave unit turning on one after the other for one second each
  • If there is some broken wire, the corresponding LED will not turn on
  • If there is some inverted wire in the cable, you will see the LEDs turning on not in a sequential order
  • The switch tells Arduino the type of cable under test (straight or cross)

This is the software:

//#define VERBOSE

char straight[8] = {2, 3, 4, 5, 6, 7, 8, 9};
char cross[8] = {4, 7, 2, 5, 6, 3, 8, 9};

void setup() {
  pinMode(2, OUTPUT);
  pinMode(3, OUTPUT);
  pinMode(4, OUTPUT);
  pinMode(5, OUTPUT);
  pinMode(6, OUTPUT);
  pinMode(7, OUTPUT);
  pinMode(8, OUTPUT);
  pinMode(9, OUTPUT);
  pinMode(12, INPUT); // Straight (normal) cable or cross cable
  pinMode(13, OUTPUT); // Control LED
#ifdef VERBOSE
  Serial.begin(9600);
#endif
}

void loop() {
  if (digitalRead(12) == LOW) { // Cross cable
#ifdef VERBOSE
    Serial.println("Cross cable");
#endif
    for (char n = 0;n < 8;n++) {
#ifdef VERBOSE
      Serial.print(n+1, DEC);
      Serial.print(": line ");
      Serial.print(cross[n]-1, DEC);
      Serial.print(" (pin ");
      Serial.print(cross[n], DEC);
      Serial.println(")");
#endif
      PulseOut(cross[n], 1000);
      PulseOut(13, 50);
    }
  } else { // Straight (normal) cable
#ifdef VERBOSE
    Serial.println("Straight cable");
#endif
    for (char n = 0;n < 8;n++) {
 #ifdef VERBOSE
      Serial.print(n+1, DEC);
      Serial.print(": line ");
      Serial.print(straight[n]-1, DEC);
      Serial.print(" (pin ");
      Serial.print(straight[n], DEC);
      Serial.println(")");
#endif
      PulseOut(straight[n], 1000);
      PulseOut(13, 50);
    }
  }
}

void PulseOut(char pin, int ms)
{
  digitalWrite(pin, HIGH);
  delay(ms);
  digitalWrite(pin, LOW);
}

The final result

These are the two separate boards of the tester (the master is the one connected to the Arduino):

And these are videos showing the cable tester at work. While testing a straight cable:

While testing a cross cable (when I change the switch):

I2C RTC DS1307 and Arduino

Posted on by
6

In this article I will:

  • describe main differences between DS1307 and PCF8563 (see this detailed article about PCF8563 on my blog before reading on)

Then, I will show how to:

  • connect DS1307 to Arduino
  • set date & time
  • get date & time with, hopefully, an optimized code

Hardware

DS1307 is an I2C real time clock that works at I2C standard mode (100 kbit/s).

From DS1307 datasheet:

The DS1307 serial real-time clock (RTC) is a low-power, full binary-coded decimal (BCD) clock/calendar plus 56 bytes of NV SRAM.
Address and data are transferred serially through an I2C, bidirectional bus.
The  lock/calendar provides seconds, minutes, hours, day, date, month, and year information.
The end of the month date is automatically adjusted for months with fewer than 31 days, including corrections for leap year.
The clock operates in either the 24-hour or 12-hour format with AM/PM indicator.
The DS1307 has a built-in power-sense circuit that detects power failures and automatically switches to the battery supply.

So the main differences between DS1307 and PCF8563 are:

  • Although not expressly stated, DS1307 works only at I2C standard mode (100 kbit/s) while PCF8563 can also work at I2C fast mode (400 kbit/s). This means that if you need to build a fast I2C circuit, as I need, you have to use PCF8563 (because every I2C component of the circuit has to be capable of running at fast mode), otherwise you can use DS1307 (that is much more common)
  • DS1307 accept a standard 3V alternate power supply (a lithium cell battery, for example) that in case of failure of the primary power supply can back up the RTC for a long time even (a lithium battery with 48mAhr or greater will back up
    the DS1307 for more than 10 years)
  • DS1307 does not have the possibility to manage alarm and timer (countdown), as PCF8563 can do
  • Other minor differences exists on how registers are organized

This is register organization of DS1307 (click to enlarge):

This is the PIN configuration of DS1307 (DIP8 package – from DS1307 datasheet):

DS1307 pin configurationWhere:

  • X1 = oscillator input
  • X2 = oscillator output
  • VBAT = backup supply input for any standard 3V lithium cell
  • GND = ground
  • SDA = serial data input and output
  • SCL = serial clock input
  • SQL/OUT = square wave/output driver
  • VCC = primary power supply

With respect to PCF8563, as far as pin configuration is concerned, the only difference is the presence of the alternate power supply pin (VBAT) in place of the interrupt pin of PCF8563 (INT). This means that if you are using only basic functions of the RTC (set date & time and get date & time) DS1307 and PCF8563 are pin-compatible.

The circuit is exactly the same as the PCF8563 (since we are not using neither alarms, timers, interrupts nor a backup battery):

Software

The code is slightly different from the code of the PCF8563. The only differences are:

  • DS1307 7 bit address is 68 (hexadecimal), while PCF8563 address is 51 (hexadecimal)
  • when reading seconds, DS1307 does not raise a bit if the integrity of the clock is not guaranteed (as PCF8563 do)
  • week day goes from 1 to 7 in DS1307 while goes from 0 to 6 in PCF8563
  • as seen, registry organization is a little bit different:
    • DS1307 does not have the century register
    • DS1307 does not have alarm and timer registers
    • Day and weekday registers are in reverse order
    • DS1307 has one control register that is the last register (PCF8563 has two control registers in first position)

Once again, the code is optimized, in a way that Arduino ask to the RTC only pieces of information that changed: this way the code can be added to an existing complex application without breaking anything (hopefully).

#include <Wire.h>//I2C header file

// Defines
//#define DEBUG // Uncomment to turn on verbose mode
#define I2C_RTC 0x68 // 7 bit address (without last bit - look at the datasheet)
#define ERROR_LED 13

// Errors
#define ERROR_RTC_SET 1 // Unable to set RTC time and date
#define ERROR_RTC_GET 2 // Unable to get RTC time and date

// Global variables
byte result;
byte second;
byte second_old; // The code ask the RTC for data only when the previous value has changed
byte minute;
byte minute_old; // The code ask the RTC for data only when the previous value has changed
byte hour;
byte hour_old; // The code ask the RTC for data only when the previous value has changed
byte weekday;
byte day;
byte month;
byte year;
char* weekdayname[] = {"Sunday", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday"};

// Function prototypes
byte BcdToDec(byte);
byte DecToBcd(byte);
void SetError(int);

void setup()
{
  pinMode(ERROR_LED, OUTPUT); // Set error LED
  Wire.begin(); // Initiate the Wire library and join the I2C bus as a master
  Serial.begin(9600); // Initiate serial communication

// Set initial date and time
  second_old = second = 53; // Second (0-59)
  minute_old = minute = 59; // Minute (0-59)
  hour_old = hour = 23; // Hour (0-23)
  weekday = 1; // Day of the week (1-7)
  day = 31; // Day (1-31)
  month = 12; // Month (1-12)
  year = 11; // Year (0-99)
  Wire.beginTransmission(I2C_RTC); // Select RTC
  Wire.send(0);        // Start address
  Wire.send(DecToBcd(second));     // Second
  Wire.send(DecToBcd(minute));    // Minute
  Wire.send(DecToBcd(hour));    // Hour
  Wire.send(DecToBcd(weekday));    // Weekday
  Wire.send(DecToBcd(day));    // Day
  Wire.send(DecToBcd(month));     // Month (with century bit = 0)
  Wire.send(DecToBcd(year));    // Year
  Wire.send(0b10000);           // Output clock frequency enabled (1 Hz)
  Wire.endTransmission();
  result = Wire.endTransmission();

#ifdef DEBUG
  Serial.print("Result of setting date and time: ");
  Serial.println(result, DEC);
#endif

  if (result) SetError(ERROR_RTC_SET);
}

void loop()
{
  Wire.beginTransmission(I2C_RTC);
  Wire.send(0); // Start address
  result = Wire.endTransmission();
#ifdef DEBUG
  Serial.print("Result of asking for date and time: ");
  Serial.println(result, DEC);
#endif
  if (result) SetError(ERROR_RTC_GET);

  Wire.requestFrom(I2C_RTC, 1);
  second = BcdToDec(Wire.receive());
  if (second != second_old) // Cycle begins only when it has changed
  {
    second_old = second;
    if (second == 0) // If second is zero I need to ask for the minute
    {
      Wire.requestFrom(I2C_RTC, 1);
      minute = BcdToDec(Wire.receive());
      if (minute != minute_old) // Cycle begins only when it has changed
      {
        minute_old = minute;
        if (minute == 0) // If minute is zero I need to ask for the hour
        {
          Wire.requestFrom(I2C_RTC, 1);
          hour = BcdToDec(Wire.receive() & 0b111111);
          if (hour != hour_old) // Cycle begins only when it has changed
          {
            hour_old = hour;
            if (hour == 0) // If hour is zero I need to ask for other elements
            {
              Wire.requestFrom(I2C_RTC, 4);
              weekday = BcdToDec(Wire.receive());
              day = BcdToDec(Wire.receive());
              month = BcdToDec(Wire.receive());
              year = BcdToDec(Wire.receive());
            }
          }
        }
      }
    }
    Serial.print(weekdayname[weekday - 1]);
    Serial.print("(");
    Serial.print(weekday, DEC);
    Serial.print(") 20");
    if (year < 10) Serial.print("0");
    Serial.print(year, DEC);
    Serial.print("-");
    if (month < 10) Serial.print("0");
    Serial.print(month,DEC);
    Serial.print("-");
    if (day < 10) Serial.print("0");
    Serial.print(day, DEC);
    Serial.print("");
    if (hour < 10) Serial.print("0");
    Serial.print(hour,DEC);
    Serial.print(":");
    if (minute < 10) Serial.print("0");
    Serial.print(minute, DEC);
    Serial.print(":");
    if (second < 10) Serial.print("0");
    Serial.println(second, DEC);
  }
}

// Converts a BCD (binary coded decimal) to decimal
byte BcdToDec(byte value)
{
  return ((value / 16) * 10 + value % 16);
}

// Converts a decimal to BCD (binary coded decimal)
byte DecToBcd(byte value){
  return (value / 10 * 16 + value % 10);
}

void SetError(int error) // Blinks forever the error led a number of times corresponding to error number
{
  while(1) // Forever
  {
    for (byte index = 0; index < error; index++)
    {
      digitalWrite(ERROR_LED, HIGH);
      delay(500);
      digitalWrite(ERROR_LED, LOW);
      delay(500);
    }
    delay(1000);
  }
}

The final result

Finally, this is the video of the DS1307 connected to the arduino. Look at what happens when I detach one of the I2C lines…

Into the wild Puglia

Posted on by
1

This summer I spent a week in Puglia (“the heel of Italy”) near Otranto, in Salento.

Take a look at the sea that you typically find down there:

To reach the sea you have to cross a pine forest a some sand dunes (that day it was exceptionally raining):

These are the dunes seen by the beach:

Below you will find other picture of the wild nature that I’ve taken during the stay.

All pictures are taken with my N900 and can be enlarged if clicked.

Animals

Flowers & plants

I2C RTC PCF8563: basic usage with Arduino

Posted on by
5

EDIT: this blog page was edited on September 24th by adding the register organization table and by reversing the order of day and weekday reading in the code (you have to read the day before of the weekday)

In this article I will show how to:

  • connect PCF8563 to Arduino
  • set date & time
  • get date & time with, hopefully, an optimized code
  • modify Wire library to run at 400 kbit/s (fast mode) instead of the standard 100 kbit/s speed

Hardware

PCF8563 is an I2C real time clock and calendar capable of working at I2C fast mode (400 kbit/s) that is the fastest I2C mode that Atmel ATmega328 (and hence Arduino) can do.

From PCF8563 datasheet:

The PCF8563 is a CMOS Real-Time Clock (RTC) and calendar optimized for low power consumption.
A programmable clock output, interrupt output, and voltage-low detector are also provided.
All addresses and data are transferred serially via a two-line bidirectional I2C-bus.
Maximum bus speed is 400 kbit/s. The register address is incremented automatically after each written or read data byte.

RTCs use registers to store pieces of information; this table describes register organization of PCF8563:

This is the PIN configuration of PCF8563 version P (DIP8 package – from PCF8563 datasheet):

Where:

  • OSCI = oscillator input
  • OSCO = oscillator output
  • INT = interrupt output (open-drain; active LOW)
  • VSS = ground
  • SDA = serial data input and output
  • SCL = serial clock input
  • CLKOUT = clock output, open-drain
  • VDD = supply voltage

As you can see, PCF8563 needs an external 32.768 kHz oscillator (quartz) to work, so we need to get one.

It is a good practice to use pull-up resistors on the I2C bus lines, so we need to get a couple of 10.000 Ω resistors.

Finally, since PCF8563 offers the possibility to output a programmable square wave on CLKOUT pin, we will connect a led (with a 470 ohm resistor) that will notify us, by blinking, that the RTC is correctly connected and initialized.

So the complete circuit, sketched with LibreOffice in Ubuntu, is:

xxxxxx

PCF8563 connected to Arduino

Different colors of lines have different meanings:

  • Black = lines connected to ground
  • Red = lines connected to supply voltage (5V)
  • Blue = I2C bus lines
  • Yellow = lines that connect the oscillator to the RTC

Finally, this is the real circuit (for practical reason I did not connect pull-up resistors, but you should do it):

Software

Please consider these aspects when looking at the code:

  • the I2C address of the RTC has to be a 7 bit address: the eighth bit is not needed since it’s used to indicate if you are reading or writing to the device (take a look here)
  • I wanted to build an optimized code, in a way that Arduino ask to the RTC only pieces of information that changed: this way the code can be added to an existing complex application without breaking anything (hopefully). This means:
    • I repeatedly ask the RTC for seconds
    • When seconds change, I ask the RTC for minutes only when seconds become equal to zero
    • When minutes change, I ask the RTC for hours only when minutes become equal to zero
    • When hours change, I ask the RTC for the remaining pieces of information (weekday, day, month, century and year) only when hours become equal to zero
  • since RTC manage numbers in BCD format, functions to convert BCD (binary coded decimal) to decimal and viceversa had to be written
  • I decided to create a register of errors and an error routine so that in case of any failure an error led will start blinking a number of times corresponding to the error number
  • just for debugging, the code displays only when needed time and date on the serial monitor
  • the RTC starts counting from 23.59.53 – December 31st, 2011

This is the code:

#include <Wire.h>//I2C header file

// Defines
//#define DEBUG // Uncomment to turn on verbose mode
#define I2C_RTC 0x51 // 7 bit address (without last bit - look at the datasheet)
#define ERROR_LED 13

// Errors
#define ERROR_RTC_SET 1 // Unable to set RTC time and date
#define ERROR_RTC_GET 2 // Unable to get RTC time and date
#define ERROR_CLOCK_INTEGRITY 3 // RTC clock integrity not guaranteed

// Global variables
byte result;
byte second;
byte second_old; // The code ask the RTC for data only when the previous value has changed
byte minute;
byte minute_old; // The code ask the RTC for data only when the previous value has changed
byte hour;
byte hour_old; // The code ask the RTC for data only when the previous value has changed
byte weekday;
byte day;
byte month;
byte year;
byte century;
char* weekdayname[] = {"Sunday", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday"};

// Function prototypes
byte BcdToDec(byte);
byte DecToBcd(byte);
void SetError(int);

void setup()
{
  pinMode(ERROR_LED, OUTPUT); // Set error LED
  Wire.begin(); // Initiate the Wire library and join the I2C bus as a master
  Serial.begin(9600); // Initiate serial communication

// Set initial date and time
  second_old = second = 53; // Second (0-59)
  minute_old = minute = 59; // Minute (0-59)
  hour_old = hour = 23; // Hour (0-23)
  weekday = 0; // Day of the week (0-6)
  day = 31; // Day (1-31)
  month = 12; // Month (1-12)
  year = 11; // Year (0-99)
  Wire.beginTransmission(I2C_RTC); // Select RTC
  Wire.send(0);        // Start address
  Wire.send(0);     // Control and status 1
  Wire.send(0);     // Control and status 2
  Wire.send(DecToBcd(second));     // Second
  Wire.send(DecToBcd(minute));    // Minute
  Wire.send(DecToBcd(hour));    // Hour
  Wire.send(DecToBcd(day));    // Day
  Wire.send(DecToBcd(weekday));    // Weekday
  Wire.send(DecToBcd(month));     // Month (with century bit = 0)
  Wire.send(DecToBcd(year));    // Year
  Wire.send(0b10000000);    // Minute alarm (and alarm disabled)
  Wire.send(0b10000000);    // Hour alarm (and alarm disabled)
  Wire.send(0b10000000);    // Day alarm (and alarm disabled)
  Wire.send(0b10000000);    // Weekday alarm (and alarm disabled)
  Wire.send(0b10000011);     // Output clock frequency enabled (1 Hz)
  Wire.send(0);     // Timer (countdown) disabled
  Wire.send(0);     // Timer value
  Wire.endTransmission();
  result = Wire.endTransmission();

#ifdef DEBUG
  Serial.print("Result of setting date and time: ");
  Serial.println(result, DEC);
#endif

  if (result) SetError(ERROR_RTC_SET);
}

void loop()
{
  Wire.beginTransmission(I2C_RTC);
  Wire.send(0x02); // Start address
  result = Wire.endTransmission();
#ifdef DEBUG
  Serial.print("Result of asking for date and time: ");
  Serial.println(result, DEC);
#endif
  if (result) SetError(ERROR_RTC_GET);

  Wire.requestFrom(I2C_RTC, 1);
  second = Wire.receive();
  if (second & 0x80) SetError(ERROR_CLOCK_INTEGRITY);
  second = BcdToDec(second & 0b01111111);
  if (second != second_old) // Cycle begins only when it has changed
  {
    second_old = second;
    if (second == 0) // If second is zero I need to ask for the minute
    {
      Wire.requestFrom(I2C_RTC, 1);
      minute = BcdToDec(Wire.receive());
      if (minute != minute_old) // Cycle begins only when it has changed
      {
        minute_old = minute;
        if (minute == 0) // If minute is zero I need to ask for the hour
        {
          Wire.requestFrom(I2C_RTC, 1);
          hour = BcdToDec(Wire.receive());
          if (hour != hour_old) // Cycle begins only when it has changed
          {
            hour_old = hour;
            if (hour == 0) // If hour is zero I need to ask for other elements
            {
              Wire.requestFrom(I2C_RTC, 4);
              day = BcdToDec(Wire.receive());
              weekday = BcdToDec(Wire.receive());
              month = Wire.receive();
              century = (month & 0x80);
              month = BcdToDec(month & 0b01111111);
              year = BcdToDec(Wire.receive());
            }
          }
        }
      }
    }
    Serial.print(weekdayname[weekday]);
    Serial.print("(");
    Serial.print(weekday, DEC);
    Serial.print(")");
    if (century)
      Serial.print(" 21");
    else
      Serial.print(" 20");
    if (year < 10) Serial.print("0");
    Serial.print(year, DEC);
    Serial.print("-");
    if (month < 10) Serial.print("0");
    Serial.print(month,DEC);
    Serial.print("-");
    if (day < 10) Serial.print("0");
    Serial.print(day, DEC);
    Serial.print("");
    if (hour < 10) Serial.print("0");
    Serial.print(hour,DEC);
    Serial.print(":");
    if (minute < 10) Serial.print("0");
    Serial.print(minute, DEC);
    Serial.print(":");
    if (second < 10) Serial.print("0");
    Serial.println(second, DEC);
  }
}

// Converts a BCD (binary coded decimal) to decimal
byte BcdToDec(byte value)
{
  return ((value / 16) * 10 + value % 16);
}

// Converts a decimal to BCD (binary coded decimal)
byte DecToBcd(byte value){
  return (value / 10 * 16 + value % 10);
}

void SetError(int error) // Blinks forever the error led a number of times corresponding to error number
{
  while(1) // Forever
  {
    for (byte index = 0; index < error; index++)
    {
      digitalWrite(ERROR_LED, HIGH);
      delay(500);
      digitalWrite(ERROR_LED, LOW);
      delay(500);
    }
    delay(1000);
  }
}

Modify Wire library to run at I2C fast mode

These are the steps to run with Arduino an I2C device at fast mode:

  1. Open header file twi.h from Arduino Wire library (in Ubuntu it is located in /usr/share/arduino/libraries/Wire/utility/)
  2. Near the top of the file look for the portion of code that define I2C speed: 
    #ifndef TWI_FREQ
#define TWI_FREQ 100000L
#endif
  3. Change it in: 
    #ifndef TWI_FREQ
#define TWI_FREQ 400000L
#endif
  4. Recompile your sketch and you’re done: it is not necessary to delete object file Wire.o and twi.o since, starting from version 0017, Arduino IDE compiles and links libraries on the fly

The final result

This short video shows the RTC working (the yellow led is blinking, that means that the RTC is running); look at what happens when I detach one of the I2C lines…

Italian style

Posted on by
Reply

Mi è sempre piaciuto volare, anche quando per necessità mi è capitato di volare settimanalmente in Italia (e per un breve periodo anche in Europa).

Ho recentemente preso un volo Alitalia per una breve vacanza al mare.

Circa un’ora dopo l’orario previsto (ma la notizia non è questa), siamo finalmente saliti a bordo e la situazione che mi si è presentata era, diciamo, sfortunatamente singolare e ho deciso di documentarla (per un attimo mi sono anche chiesto se non mi fosse convenuto scendere…).

Agli aruspici del cielo l’interpretazione dei segni: quale sarà il futuro di Alitalia?

Il bracciolo alla mia sinistra

Il bracciolo alla mia destra

Un sedile alla mia sinistra

Un pezzo del bracciolo di destra (diligentemente consegnato alla hostess)